Скрипт позволяет сохранить в лог-файл результат работы команды ping. Особенностью данного скрипта является то, что в лог-файле напротив результата прохождения каждого пакета имеется временная метка.
17:56:48 192.168.16.1: число байт=32 время=1мс TTL=255
17:56:49 192.168.16.1: число байт=32 время=1мс TTL=255
17:56:50 192.168.16.1: число байт=32 время=1мс TTL=255
...
Скрипт может быть полезен для диагностики и анализа проблем в сети.
Создайте файл pingtime.vbs:
option explicit
' conHost -- адрес хоста для слежения
' conCheckInterval -- временной интервал
const conHost = "192.168.16.1", conCheckInterval = 1000
' создаём объект:
dim soWshShell : set soWshShell = CreateObject("WScript.Shell")
WScript.Quit Main()
function WriteLog(strText)
WScript.Stdout.WriteLine FormatDateTime(Time(), vbLongTime) & " " & strText
end function
function GetHostStatus(strHost)
dim oPing : set oPing = soWshShell.Exec("ping -n 1 " & strHost)
dim strOut : strOut = ""
do
WScript.Sleep 100
if not oPing.Stdout.AtEndOfStream then
strOut = strOut & oPing.Stdout.ReadAll
end if
loop until oPing.Status = 1
dim oRegExp : set oRegExp = new RegExp
oRegExp.IgnoreCase = true
oRegExp.Pattern = "[^ ]+:.+TTL=[^\r\n]+"
dim oMatches : set oMatches = oRegExp.Execute(strOut)
if oMatches.Count > 0 then
GetHostStatus = oMatches(0).Value
else
GetHostStatus = "Inaccessible!.."
end if
end function
function Main()
do
WriteLog(GetHostStatus(conHost))
WScript.Sleep(conCheckInterval)
loop
end function
Запуск скрипта осуществляется командой cscript //nologo pingtime.vbs>pingtime.log. Результат работы сохраняется в файле pingtime.log.
Скачать pingtime.zip.
(всего оценок: 8, средняя: 5,00 из 5)